上記の広告は1ヶ月以上更新のないブログに表示されています。
新しい記事を書く事で広告が消せます。
--.--.-- -- l スポンサー広告 l top
ソフトも込みで一応動作しました。とりあえず完成とします。


良く見るとMINボタンが反対です。。。。もはやタイマーとしては使わないのでよしとします。

回路図は以下の通りです。

使っているモジュールは以下の通りです。
  ・I2C接続小型キャラクタLCDモジュール 8x2行
  ・超小型USBシリアル変換モジュール
  ・損失CMOS三端子レギュレータ 3.3V150mA

動作は動画でご覧ください。


「スポンサードリンク」

style="display:block"
data-ad-client="ca-pub-0620260288102702"
data-ad-slot="9773401572"
data-ad-format="auto">



ソフトは、ichigojam BASICのみです。4つの領域の0番にランチャー、1~3番にJampingGame,オルゴール(赤とんぼ)、モグラタタキ(オリジナルを入れています。)

まずランチャー。これをSAVE0で保存します。

100 cls:?"ICHIGO":?"mini"
110 gosub 800
120 PLAY"C8E8G8>C8":L=0
130 I=IN():IF I<>271 GOTO 130
140 I=IN()
150 IF I=269 L=1
160 IF I=13 L=2
170 IF I=270 L=3
180 IF I=271 AND L<>0 BEEP:LRUN L
190 goto 140
800 'LCD INIT
810 poke#700,64,0,2,#C0,57,17,#70,86,#6C,56,12
820 ifi2cw(62,#701,1,#704,5)?"E"
830 wait12
840 ifi2cw(62,#701,1,#709,2)?"E"
900 'LCD OUT
910 ifi2cw(62,#701,1,#702,1)+i2cw(62,#700,1,#900,8)+i2cw(62,#701,1,#703,1)+i2cw(62,#700,1,#920,8)?"E"
920 return


次にJampingKING_LCD。これは「ボクにもわかるIchigoJam マイコンボード用I2Cキャラクタ液晶LCDの接続方法」からお借りして、キー入力をスイッチに置き換えました。SAVE1で保存します。
なお、I2C LCDドライバもこのページからお借りしています。

1 'JUMPING KING LCD
5 CLS:?"JUMPING":?"KING_LCD":GOSUB 800:WAIT100
10 CLS:GOSUB800:BEEP
20 X=2:'ヨコ
30 Y=0:'タテ
40 P=0:'テンスウ
50 D=0:'ソクド
60 LET [0],95,45,95,45,255
100 'GAME
110 GOSUB 700:'Key
120 IF K=1 AND X>0 THEN X=X-1
130 IF K=2 AND X<7 THEN X=X+1
140 IF K/2=1 AND Y=0 THEN D=1
150 Y=Y+D:W=W+1
160 if Y=3 then D=-1:P=P+1
170 if Y=0 then D=0
180 IF W<5-P/5 GOTO 210
190 SCROLL 3:W=0
200 IF RND(8)=0 LC 7,1:? "."
210 T=VPEEK(X,Y<2)
220 IF T=46 GOTO 400
230 LC 5,0:?" ";P
240 LC X,Y<2:? CHR$([Y])
250 GOSUB 900
260 LC X,Y<2:? CHR$(T)
270 GOTO 100
400 'END
410 LC X,1:? "X":GOSUB 900
420 BEEP 50
430 GOSUB 700:IF K<5 GOTO 430
440 IF K=7 CLS:END
450 GOTO 1
700 'KEYPAD
710 K=IN():IF K=270 K=2
720 IF K=269 K=1
730 IF K=13 BEEP:LRUN 0
740 RETURN
800 'LCD INIT
810 poke#700,64,0,2,#C0,57,17,#70,86,#6C,56,12
820 ifi2cw(62,#701,1,#704,5)?"E"
830 wait12
840 ifi2cw(62,#701,1,#709,2)?"E"
900 'LCD OUT
910 ifi2cw(62,#701,1,#702,1)+i2cw(62,#700,1,#900,8)+i2cw(62,#701,1,#703,1)+i2cw(62,#700,1,#920,8)?"E"
920 return



次にオルゴール(赤とんぼ)。オリジナルです。SAVE2で保存してます。

100 cls:?"AKATONBO"
110 gosub 800
200 PLAY"T60O3G8O4C8C4.D8E8G8O5C8O4A8G4A8C8C4D4E2R4"
210 IF SOUND()=1 GOTO 210
230 PLAY"T60O4E8A8G4.A8O5C8O4A8G8A8G8E8G8E8C8E8D8C8C2R4"
240 IF SOUND()=1 GOTO 240
300 WAIT 10:LRUN 0
800 'LCD INIT
810 poke#700,64,0,2,#C0,57,17,#70,86,#6C,56,12
820 ifi2cw(62,#701,1,#704,5)?"E"
830 wait12
840 ifi2cw(62,#701,1,#709,2)?"E"
900 'LCD OUT
910 ifi2cw(62,#701,1,#702,1)+i2cw(62,#700,1,#900,8)+i2cw(62,#701,1,#703,1)+i2cw(62,#700,1,#920,8)?"E"
920 return


最後にモグラタタキ。動画では分かりにくいと思いますが、モグラの出具合を数字で表現しており、0になる前に下に行って叩く、というゲームになっています。あまり面白くないオリジナルです。SAVE3で保存してます。

50 CLS:S=0:GOSUB900
60 ?"*MOGURA*":?"*TATAKI*":GOSUB900:WAIT100
100 X=2:FORI=0TO5:[I]=0:NEXT
110 K=IN():CLS
120 IF K=269 AND X>0 X=X-1:PLAY"E32"
130 IF K=270 AND X<5 X=X+1:PLAY"E32"
140 LCX,1:?"H";
150 LC0,0:FORI=0TO5
160 IF[I]=0AND RND(30)=1 [I]=10
170 IF[I]>0:[I]=[I]+1:?5-[I]/10;ELSE ?".";
180 IF [I]>50 GOTO 300
190 NEXT
195 IF K=13 AND [X]>0 LCX,0:?"*";:PLAY"C32D32":S=S+10:[X]=0
196 GOSUB800
200 GOTO 110
300 PLAY"O4C8O3G8E8C8":CLS:?"SCORE":LC0,1:?S:GOSUB900
310 WAIT 100:LRUN 0
800 'LCD INIT
810 poke#700,64,0,2,#C0,57,17,#70,86,#6C,56,12
820 ifi2cw(62,#701,1,#704,5)?"E"
830 wait12
840 ifi2cw(62,#701,1,#709,2)?"E"
900 'LCD OUT
910 ifi2cw(62,#701,1,#702,1)+i2cw(62,#700,1,#900,8)+i2cw(62,#701,1,#703,1)+i2cw(62,#700,1,#920,8)?"E"
920 return

ランチャーだけ使って、あとは1~3に自由なプログラムを入れてしまえば、好きなichigojamソフトの実行専用機になるわけです。

MINボタンを除けば結構見栄え良くできたかと思っています。何かこれならではの活用方法を考えようかと思います。
例えば元々の機能のタイマーにしてももっと高機能なものができますね。
電池が1時間くらいしか持たず、交換困難なのがネックですが。



2015.10.20 Tue l ICHIGOJAM l コメント (1) l top

コメント

No title
相互リンクのご連絡 お世話になります。貴サイト拝見しまして非常に良いコンテンツを配信されており勝手ながらリンク集に追加させていただきました。(以下URLのヘッダはスパム対策で外していますが、こちらです) konkatsuhack.website/ 相互リンク、ぜひご検討いただければ幸いです。管理人 
2015.10.23 Fri l 管理人. URL l 編集

コメントの投稿












上記広告は1ヶ月以上更新のないブログに表示されています。新しい記事を書くことで広告を消せます。