上記の広告は1ヶ月以上更新のないブログに表示されています。
新しい記事を書く事で広告が消せます。
--.--.-- -- l スポンサー広告 l top
プログラムエリアへのデータ書き込み方法が分かりましたので、キャラクタエディタを作ってみました。
コンセプトとしてichigojam単体で使えるようにしています。




「スポンサードリンク」

style="display:block"
data-ad-client="ca-pub-0620260288102702"
data-ad-slot="9773401572"
data-ad-format="auto">




動作は動画を見てください。


ソースは以下の通りです。
1 '0000000000000000????????????????0000000000000000????????????????0000000000000000????????????????0000000000000000????????????????
10 Q=0:P=#700+Q*64:FOR I=0TO63:POKE P+I,(PEEK(#C04+I*2)-#30)*16+PEEK(#C05+I*2)-#30:NEXT:A=0
20 CLS:FOR I=0TO7:LC3*I,0:?HEX$(#E0+Q*8+I);:LC3*I,1:?CHR$(#E0+Q*8+I);:NEXT:LC3*A,2:?"+";
30 LC2,4:?"01234567";:FOR Y=0TO7:LC1,5+Y:?CHR$(#41+Y);:B=PEEK(P+A*8+Y):FOR X=0TO7:C=(B&(1<<(7-X)))>>(7-X):LC2+X,5+Y:?CHR$(C);:NEXT:NEXT:X=2:Y=5:T=0
40 B=VPEEK(X,Y)
50 K=INKEY():IF K=0LC X,Y:?"+";:WAIT5:LC X,Y:?CHR$(B);:WAIT5:GOTO50
60 LC X,Y:IF#2FK:A=K-#30:GOTO20
70 IF K=88ORK=90?CHR$((K-88)/2):GOTO40
80 IF K=29ANDX<9X=X+1
90 IF K=28ANDX>2X=X-1
100 IF K=31ANDY<12Y=Y+1
110 IF K=30ANDY>5Y=Y-1
120 IF K=10 X=2:IF Y<12Y=Y+1
130 IF K=65 FOR V=0TO7:B=0:FOR W=0TO7:B=(B<<1)+VPEEK(W+2,V+5):NEXT:POKE P+A*8+V,B:NEXT:GOTO20
140 IF K=83 LC0,15:?"saving":FOR I=0TO63:B=PEEK(P+I):POKE#C04+I*2,(B/16)+48:POKE#C05+I*2,(B%16)+48:NEXT:LIST1:END
900 GOTO40

================================
◆機能は以下の通りです。
================================
・8キャラクタから選択、キー操作で編集可能です。
・10行にあるQを0~3に変えることで以下のキャラクタコードに対応します。
  Q=0 : #E0-#E7 , Q=1 : #E8-#Ef , Q=2 : #F0-#F7 , Q=3 : #F8-#FF
・1行目のコメント内にデータを1バイト二桁で書き込みます。
 書きこむ際に0~Fを#30~#3Fに置き換えていますので、数値0~9は
 数字として見えますが、A~Fは記号になってしまいます。
・編集後の1行と10行だけ残して、その先に他のプログラムを記述することで
 編集したキャラクタを使うことができます。

※1行のコメント内容を変更することはOKですが、長さを変えないようにしてください。
  特に短くしてしまうとプログラムが壊れます。

================================
◆キー操作
================================
・0~7キー     : 編集するキャラクタを選択します。
              選択したキャラクタの下に”+”が表示されます。
・上下左右キー  :編集画面のカーソル”+”移動です。
・Zキー       :カーソル位置のドットをオンにします。
・Xキー       :カーソル位置のドットをオフにします。
・リターンキー   :カーソル位置が一段下の左はじに移動します。
・Aキー       :編集画面の内容を編集中のキャラクタデータに書き込みます。
・Sキー       :8キャラクタ分のデータをプログラム内(1行目のコメント)に書き込みます。

それではまたです。



2015.05.09 Sat l ICHIGOJAM l コメント (0) l top

コメント

コメントの投稿












上記広告は1ヶ月以上更新のないブログに表示されています。新しい記事を書くことで広告を消せます。