上記の広告は1ヶ月以上更新のないブログに表示されています。
新しい記事を書く事で広告が消せます。
--.--.-- -- l スポンサー広告 l top
ソフトも込みで一応動作しました。とりあえず完成とします。


良く見るとMINボタンが反対です。。。。もはやタイマーとしては使わないのでよしとします。

回路図は以下の通りです。

使っているモジュールは以下の通りです。
  ・I2C接続小型キャラクタLCDモジュール 8x2行
  ・超小型USBシリアル変換モジュール
  ・損失CMOS三端子レギュレータ 3.3V150mA

動作は動画でご覧ください。


「スポンサードリンク」

style="display:block"
data-ad-client="ca-pub-0620260288102702"
data-ad-slot="9773401572"
data-ad-format="auto">



ソフトは、ichigojam BASICのみです。4つの領域の0番にランチャー、1~3番にJampingGame,オルゴール(赤とんぼ)、モグラタタキ(オリジナルを入れています。)

まずランチャー。これをSAVE0で保存します。

100 cls:?"ICHIGO":?"mini"
110 gosub 800
120 PLAY"C8E8G8>C8":L=0
130 I=IN():IF I<>271 GOTO 130
140 I=IN()
150 IF I=269 L=1
160 IF I=13 L=2
170 IF I=270 L=3
180 IF I=271 AND L<>0 BEEP:LRUN L
190 goto 140
800 'LCD INIT
810 poke#700,64,0,2,#C0,57,17,#70,86,#6C,56,12
820 ifi2cw(62,#701,1,#704,5)?"E"
830 wait12
840 ifi2cw(62,#701,1,#709,2)?"E"
900 'LCD OUT
910 ifi2cw(62,#701,1,#702,1)+i2cw(62,#700,1,#900,8)+i2cw(62,#701,1,#703,1)+i2cw(62,#700,1,#920,8)?"E"
920 return


次にJampingKING_LCD。これは「ボクにもわかるIchigoJam マイコンボード用I2Cキャラクタ液晶LCDの接続方法」からお借りして、キー入力をスイッチに置き換えました。SAVE1で保存します。
なお、I2C LCDドライバもこのページからお借りしています。

1 'JUMPING KING LCD
5 CLS:?"JUMPING":?"KING_LCD":GOSUB 800:WAIT100
10 CLS:GOSUB800:BEEP
20 X=2:'ヨコ
30 Y=0:'タテ
40 P=0:'テンスウ
50 D=0:'ソクド
60 LET [0],95,45,95,45,255
100 'GAME
110 GOSUB 700:'Key
120 IF K=1 AND X>0 THEN X=X-1
130 IF K=2 AND X<7 THEN X=X+1
140 IF K/2=1 AND Y=0 THEN D=1
150 Y=Y+D:W=W+1
160 if Y=3 then D=-1:P=P+1
170 if Y=0 then D=0
180 IF W<5-P/5 GOTO 210
190 SCROLL 3:W=0
200 IF RND(8)=0 LC 7,1:? "."
210 T=VPEEK(X,Y<2)
220 IF T=46 GOTO 400
230 LC 5,0:?" ";P
240 LC X,Y<2:? CHR$([Y])
250 GOSUB 900
260 LC X,Y<2:? CHR$(T)
270 GOTO 100
400 'END
410 LC X,1:? "X":GOSUB 900
420 BEEP 50
430 GOSUB 700:IF K<5 GOTO 430
440 IF K=7 CLS:END
450 GOTO 1
700 'KEYPAD
710 K=IN():IF K=270 K=2
720 IF K=269 K=1
730 IF K=13 BEEP:LRUN 0
740 RETURN
800 'LCD INIT
810 poke#700,64,0,2,#C0,57,17,#70,86,#6C,56,12
820 ifi2cw(62,#701,1,#704,5)?"E"
830 wait12
840 ifi2cw(62,#701,1,#709,2)?"E"
900 'LCD OUT
910 ifi2cw(62,#701,1,#702,1)+i2cw(62,#700,1,#900,8)+i2cw(62,#701,1,#703,1)+i2cw(62,#700,1,#920,8)?"E"
920 return



次にオルゴール(赤とんぼ)。オリジナルです。SAVE2で保存してます。

100 cls:?"AKATONBO"
110 gosub 800
200 PLAY"T60O3G8O4C8C4.D8E8G8O5C8O4A8G4A8C8C4D4E2R4"
210 IF SOUND()=1 GOTO 210
230 PLAY"T60O4E8A8G4.A8O5C8O4A8G8A8G8E8G8E8C8E8D8C8C2R4"
240 IF SOUND()=1 GOTO 240
300 WAIT 10:LRUN 0
800 'LCD INIT
810 poke#700,64,0,2,#C0,57,17,#70,86,#6C,56,12
820 ifi2cw(62,#701,1,#704,5)?"E"
830 wait12
840 ifi2cw(62,#701,1,#709,2)?"E"
900 'LCD OUT
910 ifi2cw(62,#701,1,#702,1)+i2cw(62,#700,1,#900,8)+i2cw(62,#701,1,#703,1)+i2cw(62,#700,1,#920,8)?"E"
920 return


最後にモグラタタキ。動画では分かりにくいと思いますが、モグラの出具合を数字で表現しており、0になる前に下に行って叩く、というゲームになっています。あまり面白くないオリジナルです。SAVE3で保存してます。

50 CLS:S=0:GOSUB900
60 ?"*MOGURA*":?"*TATAKI*":GOSUB900:WAIT100
100 X=2:FORI=0TO5:[I]=0:NEXT
110 K=IN():CLS
120 IF K=269 AND X>0 X=X-1:PLAY"E32"
130 IF K=270 AND X<5 X=X+1:PLAY"E32"
140 LCX,1:?"H";
150 LC0,0:FORI=0TO5
160 IF[I]=0AND RND(30)=1 [I]=10
170 IF[I]>0:[I]=[I]+1:?5-[I]/10;ELSE ?".";
180 IF [I]>50 GOTO 300
190 NEXT
195 IF K=13 AND [X]>0 LCX,0:?"*";:PLAY"C32D32":S=S+10:[X]=0
196 GOSUB800
200 GOTO 110
300 PLAY"O4C8O3G8E8C8":CLS:?"SCORE":LC0,1:?S:GOSUB900
310 WAIT 100:LRUN 0
800 'LCD INIT
810 poke#700,64,0,2,#C0,57,17,#70,86,#6C,56,12
820 ifi2cw(62,#701,1,#704,5)?"E"
830 wait12
840 ifi2cw(62,#701,1,#709,2)?"E"
900 'LCD OUT
910 ifi2cw(62,#701,1,#702,1)+i2cw(62,#700,1,#900,8)+i2cw(62,#701,1,#703,1)+i2cw(62,#700,1,#920,8)?"E"
920 return

ランチャーだけ使って、あとは1~3に自由なプログラムを入れてしまえば、好きなichigojamソフトの実行専用機になるわけです。

MINボタンを除けば結構見栄え良くできたかと思っています。何かこれならではの活用方法を考えようかと思います。
例えば元々の機能のタイマーにしてももっと高機能なものができますね。
電池が1時間くらいしか持たず、交換困難なのがネックですが。



スポンサーサイト
2015.10.20 Tue l ICHIGOJAM l コメント (1) l top
ハードはほぼ完成しました。
これが最初に組んでみたところ。左側が下側モールド、右側が上蓋です。下側モールドの苺の先にUSBシリアル、あとはCR2032電池ホルダ、水色のが圧電スピーカ、そしてichigojamチップとなっています。


「スポンサードリンク」

style="display:block"
data-ad-client="ca-pub-0620260288102702"
data-ad-slot="9773401572"
data-ad-format="auto">


これで一応動いたのですが、動かしてみてCR2032では10分くらいしか持たないことが分かりました。
そこでもうひとつ上のCR2450に交換しました。これで容量3倍です。
しかしCR2450のサイズでは電池ホルダはとても入らないので、テープで電極を固定するようにしています。


あとから試したところ、これでも1時間くらいしかバッテリがもたないみたいです。
交換が大変なので、普段はUSBシリアルから電源を取れるようにしました。回路図は次回アップします。

で、ケースを合わせたところです。結構良い感じに見えます。



この装置はCRTもキーボードも繋がりませんので、USBシリアルからプログラムする実行専用機となります。
3つある押しボタンスイッチの一つをBTNにしていますので、それを押しながら起動で、プログラム0領域にランチャーを置いておいて起動。そこから他3つの領域のプログラムを選択実行する予定です。そのあたりを次回動画付きの記事にしたいと思います。


2015.10.20 Tue l 未分類 l コメント (0) l top
まずは秋月の超小型キャラクタLCDをケースに入れて動かしてみました。

変換基板につけるとケースに入らないので配線をLCD直付けで行っています。
初めにLCDの裏側をテープで保護します。これは結構大事です。LCDの裏側にちょっとでも傷を付けると、それが表示面に見えてしまいます。実はこの配線の前にそれでひとつダメにしてしまいました。。。。。
ちょっと分かりにくいですが、テープを張った裏側はこんな感じになります。


配線してケースに入れたところです。配線は秋月のデータシートに従っていますが、3点注意が有ります。
   ①秋月のデータシートにはリセット信号の配線が有りませんが、プルアップが必要です。
   ②SDA/SCLにもプルアップが必要です。
   ③VCC-GND間に普通は0.1uF位のパスコンを入れますが、今回配線後に電源波形を見たら
    非常に大きなりプルが乗っていたので10uFにしました。

2つあるスイッチはタクトスイッチをホットボンドで固定しています。

「スポンサードリンク」

style="display:block"
data-ad-client="ca-pub-0620260288102702"
data-ad-slot="9773401572"
data-ad-format="auto">



この状態でichigojamに繋いだ所。ichigojamはI2C-LCD用のドライバが公開されているので、そのドライバとサンプルソフトを動かしてみました。

実にあっさり動きました。ichigojamのお手軽さは大したものです。今回はソフト何も作らずに行けています。


次はいよいよichigojam本体をケースにいれてスタンドアローン化していきます。




2015.10.18 Sun l ICHIGOJAM l コメント (0) l top
昨日100円ショップを物色していて、以下のキッチンタイマーに目がとまりました。


ichigojamケースとしか言いようがないデザインですが、目がとまった理由はそれだけではなく、LCDのサイズにもよります。
以前使用した秋月の超小型LCDモジュール[AQM0802A-RN-GBW]と同じくらいではないか、と気付きました。


手持ちにひとつ有ったので並べてみたところ、どうみてもぴったりです。

「スポンサードリンク」



style="display:block"
data-ad-client="ca-pub-0620260288102702"
data-ad-slot="9773401572"
data-ad-format="auto">




分解して、

余計な突起部分をニッパでバキバキとカットして

秋月のLCDを乗っけたところ。やはりぴったりです。


それではいまから中にichigojamを入れる工作に入ります。





2015.10.18 Sun l ICHIGOJAM l コメント (0) l top
PANCAKEの画面に色がつかず、表示がスクロールする件につきまして、水晶振動子の両端にコンデンサを付ければ改善されるかもしれない、ということで実験してみました。

まずオシロで周波数を見てみますと、14.318MHz期待のところ14.32MHzと出ました。
精度がMHz以下2桁しかないオシロの測定機能精度では測れないですね。NTSCカラーはとてもシビアみたいです。


手元にあった12pFのコンデンサが有ったので両端に付けてみました。



「スポンサードリンク」



style="display:block"
data-ad-client="ca-pub-0620260288102702"
data-ad-slot="9773401572"
data-ad-format="auto">



その結果、以下のように色は出ましたのである程度改善したようです。ここでオシロで再度測定しましたが、やっぱり14.32MHzと出ました。
しかしまだゆっくりとスクロールしています。


別のAITENDO小型モニタに繋いだところ、綺麗に安定して表示されました。


他に、居間にある大型のテレビでも試したところ、そちらも正常表示できました。
うちにあるモニタでは2/3がうまく表示できたことになります。
トリマコンデンサをつけて微調整すればもう一台もできるのではないかと思いますが、とりあえず小型モニタで使えればよいのでここまでといたします。




2015.10.18 Sun l ICHIGOJAM l コメント (0) l top
土曜日に秋葉原に行きましたので、AITENDOで「こどもマルチメディアボード「ai.cake」キット [K-ai.cake]」 を買ってきました。



今朝少し早起きしましたので、ハンダ付けしてみたところ。

しかしディスプレイに繋いでも何も表示されませんでした。


ハンダ付けを見直し、テスタで電源やリセットを見ましたが特に異常なし。しかたなくオシロを繋いでみたところ、VIDEOOUTは全く動いていません。しかし他をあたっていたら、1ピンと2ピンに見たことが有るような周期信号が出ているのに気付きました。
たしかここはichigojamのビデオ出力のはず、と思ってichigojam回路図をみたら確かにその通りです。

では、このチップにはichigojamファームが書いてあるのでは?と思い、CPUを外してichigojamボードに乗せました。

それが正解で、ichigojamの起動メッセージが表示されました。

「スポンサードリンク」

style="display:block"
data-ad-client="ca-pub-0620260288102702"
data-ad-slot="9773401572"
data-ad-format="auto">


そこで、ichigojamボードに乗せたままでMagicFlashを使ってPANCAKEファームを書き込みます。


ようやくPANCAKEの表示が出てきました。やれやれ。

このモニタでは色がきちんと出ておらず、画面が上にスクロールしています。相性がよくないのでしょう。別のモニタにしようかと思います。


ファームの書き違いか、袋詰め時のCPUの入れ間違いなのでしょう。AITENDOさんらしいところです。
ネットの在庫を見ると私が買った書き込みチップ付きは「在庫なし」になっていますが、こういう不具合が有ったので確認と交換のため見合わせているとかでしょうか?

店舗には複数置いてあったので同じ間違いの物を他にも買った人がおられるのではないでしょうか?
私はたまたまオシロで見たのでわかりましたが、持っている人は少ないでしょうから、こういう間違いは中々分からないですね。
購入された方、これから購入の方で、表示が出ない場合はPANCAKEファーム更新をお試しください。

2015.10.12 Mon l ICHIGOJAM l コメント (2) l top
久しぶりにichigojamから離れまして、鉱石ラジオの話です。

実は先月所用で北米に一週間くらい出かけていまして、テキサス州のダラスにも一日滞在しました。
その時に土産物屋で鉱物詰め放題一袋$7というのをみつけました。複数種類の鉱物があって、別売$2の袋を買うとその中に入るだけ買える、というものです。(残念ながらそのコーナの写真を撮るのを忘れてしまいました。)
その鉱物の中に黄鉄鉱が入っていたので、それだけ詰めん込んできたものです。

「スポンサードリンク」

style="display:block"
data-ad-client="ca-pub-0620260288102702"
data-ad-slot="9773401572"
data-ad-format="auto">



今日思い立って鉱石ラジオにしました。イメージと回路図は以下の通りです。アンテナは電灯線アンテナです。

Crystal Radio

結果、今は東京都練馬区にいるのですが、FEN1曲だけなんとか聞えました。音は非常に微かです。
どれだけ微かかわかるように動画にして見ました。

音量は微かではありますが、あたりは良いようで、検波されるポイントはそれほど気を使わずとも適当に針を当てているとだいたいの場所で音が聞こえます。場所による音の大小が多少あり、少しでも大きいところを探すのも結構楽しみではあります。

後で数えたら35個入っていました。1個あたり30円程度でしょうか。御徒町のストーンショップで500円位で売っているのを見たことが有り、それに比べるとかなりお買い得と思いました。


それではまたです。
2015.10.12 Mon l 未分類 l コメント (2) l top
(Faebookでのご指摘によると、PWM機能が搭載されているのは1.0.2 beta11から1.1.0 beta1ということです。この記事ではichigojam-1.1b5_jpmnをFacebook ichigojamグループからダウンロードして使っています。)

PWMのパルス幅の方を制御してエンベロープ的な強弱制御を追加してみました。

ハードは前回と同じで、OUT3、OUT5に圧電スピーカを繋ぎます。


原理は簡単で、いままではPWM命令を発行する際にPWM周期の1/2または1/4を固定として与えていたところを、変動させるようにしただけです。

エンベロープ有る無しで違いが分かる動画にしましたのでご覧ください。
違いが分かるように曲は打楽器系のリズムが入るボレロにして見ました。主旋律は強弱を微妙に振るようにし、リズムは急激に弱くなるように設定しました。



ぽこぽこ音がするのは多分PWM周期切り替えのところで中途半端なパルスが出ているのではないかと思いますが、対処方法が思いつきません。多分フィルタをかければ消えるのでしょうが、できればハードは追加したくないし。。。。

「スポンサードリンク」

style="display:block"
data-ad-client="ca-pub-0620260288102702"
data-ad-slot="9773401572"
data-ad-format="auto">




プログラムは以下の通りです。まずは曲データ。
リズムパートについては、データ254を検出するとデータの頭に戻るようにしました。
これで同じリズムを繰り返しますので、メモリを節約できます。

10 let[0],1,909,858,810,764,722,681,643,607,573,541
20 LET [11],510,482,455,429,405,382,361,341,321,303
30 LET [21],286,270,255,241,227,215,202,191,180,170
40 LET [31],161,152,143,135,128,120,114,107,101,96
50 LET [41],90,85,80,76,72,68,64,60,57,54,51,48
60 POKE #700,0,72,0,72,28,36,27,6,28,6,30,6,28,6,27,6,25,6,28,12
70 POKE #714,28,6,25,6,28,36,27,6,28,6,25,6,23,6,20,6
80 POKE #724,21,6,23,54,21,6,20,6,18,6,20,6,21,6,23,6
90 POKE #734,25,6,23,54,25,6,27,6,25,6,23,6,21,6,20,6
100 POKE #744,18,6,20,6,18,6,16,24,16,6,18,6,20,12,21,12
110 POKE #754,18,24,23,48,255,255
200 POKE #780,23,12,23,4,23,4,23,4,23,12,23,4,23,4,23,4,23,12,23,12,254,255


次が演奏プログラム。演奏中はVideo0で表示を止めるようにしました。
これで数倍速くなりますのでエンベロープ制御がスムーズになります。

5 CLS:?"*** ボレロ ***":?" ":?" 1:フツウ":?" 2:エンベロープ・":?""
6 INPUT " ドチラ??カ ? ",P
7 IF P=1 P=60 ELSE P=50
10 A=#700:B=#780:C=0:D=0:E=0:F=0:V=1:VIDEO 0
15 '********* PART1******
20 IF A=0 GOTO 120
30 IF D>0 GOTO P
40 C=PEEK(A):D=PEEK(A+1):A=A+2
50 IF C=255 A=0:PWM 3,1,1:PWM5,1,1:GOTO210 ELSE PWM3,[C]/2+1+V,[C]:V=-V
60 D=D-1:IF D=1 :PWM 3,1,1
115 '********* PART2 **********
120 IF B=0 GOTO 200
130 IF F>0 GOTO P+100
140 E=PEEK(B):F=PEEK(B+1):B=B+2:IF E<100 G=[E]/4
150 IF E=254 B=#780:GOTO 140 ELSE PWM5,G,[E]:G=G/10
160 F=F-1:IF F=1 :PWM 5,1,1
200 WAIT 2:IF A>0 OR B>0 GOTO 20
210 VIDEO 1:GOTO 5



和音、エンベロープができたら、音色制御もやってみたいところですが、さすがにソフトだけでは難しいですね。


2015.10.09 Fri l ICHIGOJAM l コメント (0) l top
(Faebookでのご指摘によると、PWM機能が搭載されているのは1.0.2 beta11から1.1.0 beta1ということです。この記事ではichigojam-1.1b5_jpmnをFacebook ichigojamグループからダウンロードして使っています。)

PWMを用いた演奏原理とデータ形式について解説いたします。

まずPWM周期の設定方法、ichigojamのPWM周期は0.01ms単位で設定可能です。

そのため、発声したい音程の周波数fから周期tを求め、それを0.01msで割ることで対応したPWM周期を計算することができます。下の表にA1~C6の周波数とPWM周期の変換を示します。



前回のデモ演奏は、PWM周期をこの値とし、PWM幅はそれを2又は4で割ったものとしています。主旋律が1/2(DUTY50%)、副旋律が1/4(DUTY25%)です。これによって主旋律の方が大きめの音になっているはずです。


「スポンサードリンク」

style="display:block"
data-ad-client="ca-pub-0620260288102702"
data-ad-slot="9773401572"
data-ad-format="auto">



次に、楽譜データです。楽譜データは、1符号に着き、音階番号+長さの2バイト構成になっています。
音階番号はA1~C6に対して下のように割り振った番号です。



長さは適当なのですが、四分音符を8と定義しており、それを基準として、十六分音符は2、八分音符は4、二分音符は16、全音符なら32となります。付点が付く場合はそれぞれを1.5倍とします。

楽譜データの最後は255,255としておくとそのパートの演奏を終了します。

基本構成はできましたので、この次はちょっと演奏プログラムに細工してエンベロープ、ビブラート等を付けてみようかと思います。

それではまたです。

2015.10.08 Thu l ICHIGOJAM l コメント (0) l top
ichigojamの1.0.2βから追加されたPWM機能で2和音音楽をやってみました。

PWM2系統による和音実験です。

(Faebookでのご指摘によると、PWM機能が搭載されているのは1.0.2 beta11から1.1.0 beta1ということです。この記事ではichigojam-1.1b5_jpmnをFacebook ichigojamグループからダウンロードして使っています。)

ハードは非常に簡単で、圧電ブザーの2端子をOUT3,OUT5に繋ぐだけです。
圧電ブザーは大きめの物を使った方が音がよくなるようです。この写真は秋月電子で2個100円の物です。



これで、PWM3,PWM5命令で異なるパートを出力します。

音は動画で見てください。



「スポンサードリンク」

style="display:block"
data-ad-client="ca-pub-0620260288102702"
data-ad-slot="9773401572"
data-ad-format="auto">



ソースをコピーします。
まずは音階定義と「さくらさくら」の楽譜定義。音階定義は音程ごとの周波数に対応したPWM周期を配列に入れます。
楽譜はPCGエリア#700-#7FFに置きました。このため定義が書いてあったら壊してしまうのでご注意ください。

10 let[0],1,909,858,810,764,722,681,643,607,573,541
20 LET [11],510,482,455,429,405,382,361,341,321,303
30 LET [21],286,270,255,241,227,215,202,191,180,170
40 LET [31],161,152,143,135,128,120,114,107,101,96
50 LET [41],90,85,80,76,72,68,64,60,57,54,51,48
60 POKE #700,25,8,25,8,27,16,25,8,25,8,27,16,25,8,27,8
70 POKE #710,28,8,27,8,25,8,27,4,25,4,21,16,20,8,16,8
80 POKE #720,20,8,21,8,20,8,20,4,16,4,15,16,25,8,27,8
90 POKE #730,28,8,27,8,25,8,27,4,25,4,21,16,20,8,16,8
100 POKE #740,20,8,21,8,20,8,20,4,16,4,15,16,255,255
200 POKE #780,0,16,0,4,32,4,28,4,27,4,0,16,0,4,32,4
210 POKE #790,28,4,27,4,0,4,20,4,0,4,20,4,0,4,20,4
220 POKE #7A0,0,4,20,4,0,4,20,4,0,4,20,4,0,4,30,4
230 POKE #7B0,28,4,21,4,20,4,0,4,0,24,0,16,0,4,32,4
240 POKE #7C0,33,4,32,4,0,4,20,4,0,4,20,4,0,4,20,4
250 POKE #7D0,0,4,20,4,0,4,20,4,0,4,20,4,0,4,30,4
260 POKE #7E0,28,4,21,4,20,4,0,4,0,8,0,16,0,16,0,4,32,4,33,4,32,4,255,255


次に演奏プログラム。各パートの音階と長さを取出しながらPWM操作をします。
10 A=#700:B=#780:C=0:D=0:E=0:F=0
15 '********* PART1 0 IF A=0 GOTO 120
20 IF A=0 GOTO 120
30 IF D>0 GOTO 60
40 C=PEEK(A):D=PEEK(A+1):A=A+2
50 IF C=255 A=0:PWM 3,1,1 ELSE PWM3,[C]/2,[C]
60 D=D-1:IF D=1 :PWM 3,1,1
115 '********* PART2 **********
120 IF B=0 GOTO 200
130 IF F>0 GOTO 160
140 E=PEEK(B):F=PEEK(B+1):B=B+2
150 IF E=255 B=0:PWM 5,1,1 ELSE PWM5,[E]/4,[E]
160 F=F-1:IF F=1 :PWM 5,1,1
200 WAIT 7:IF A>0 OR B>0 GOTO 20
210 END


データ形式や原理説明は時間ができた時に別記事で解説いたします。

また、やりようによってはエンベロープ等も付けられそうなので、もう少し改善したいと思います。

それではまたです。






2015.10.07 Wed l ICHIGOJAM l コメント (0) l top
上記広告は1ヶ月以上更新のないブログに表示されています。新しい記事を書くことで広告を消せます。